//-----HOW TO USE THIS MACRO-----
//Open this text file in Fiji, from "Language" manu select "IJ1 Macro". Adjust the value of variables to fit your image, and "Run".
//-------------------------------------------------------------------------------------
Threshold = 10;			    // threshold used to segment cells from background
IncreaseRadius = 10;		// increase in diameter in micrometer
x = 223; y = 220; d = 77    //makeOval(x, y, d, d); numbers need to match the location of beads
r = d / 2
run("Clear Results");
roiManager("Reset");

list = getList("window.titles");
for (i=0; i<list.length; i++) {
  	if (list[i]=="Results") {
  		selectWindow("Results");
  		run("Close");
  		}
	  	if (list[i]=="Summary of StackCircles") {
  		selectWindow("Summary of StackCircles");
  		run("Close");
  		}
  	}

list = getList("image.titles");
for (i=0; i<list.length; i++) {
  		if (list[i]=="MaxProjection") {
  		selectWindow("MaxProjection");
  		run("Close");
  		}
  		if (list[i]=="StackCircles") {
  		selectWindow("StackCircles");
  		run("Close");
  		}
  		if (list[i]=="temp") {
  		selectWindow("temp");
  		run("Close");
  		}  	
  	}


run("Duplicate...", "title=temp duplicate channels=2");
run("Median...", "radius=1 stack");
run("Z Project...", "projection=[Max Intensity]");
rename("MaxProjection");
getDimensions(width, height, channels, slices, frames);

run("Duplicate...", "title=ColorCoded");
run("RGB Color");
selectWindow("MaxProjection");
setThreshold(Threshold, 255);
run("Analyze Particles...", "size=100-Infinity add stack");
selectWindow("ColorCoded");
roiManager("OR");
run("Clear Outside");
setForegroundColor(0, 255, 0);
run("Fill");
roiManager("Reset");
selectWindow("MaxProjection");
setThreshold(Threshold, 255);
selectWindow("ColorCoded");
makeOval(x, y, d, d);
roiManager("Add");
setForegroundColor(255, 0, 0);
run("Fill");

run("Split Channels");

selectWindow("ColorCoded (red)");
roiManager("Select", 0);
OldArea = getResult("Area",0);
run("Set Measurements...", "center");
roiManager("Measure");
CenterOfMass_X = getResult("XM",0);
toUnscaled(CenterOfMass_X);
CenterOfMass_Y = getResult("YM",0);
toUnscaled(CenterOfMass_Y);
selectWindow("Results");
run("Close");
roiManager("Reset");


//Calculate center of  circles and max number of circles
if (CenterOfMass_X <= width/2) {
	DistanceToEdge_X = CenterOfMass_X;
	}
else {
	DistanceToEdge_X = width - CenterOfMass_X;
	}
if (CenterOfMass_Y <= height/2) {
	DistanceToEdge_Y = CenterOfMass_Y;
	}
else {
	DistanceToEdge_Y = height -	CenterOfMass_Y;
	}
if (DistanceToEdge_X <= DistanceToEdge_Y) {
	MaxDistanceToCenter = DistanceToEdge_X;
	}
else {
	MaxDistanceToCenter = DistanceToEdge_Y;
	}	

toScaled(MaxDistanceToCenter);
NrOfCircles = floor((MaxDistanceToCenter-d)/IncreaseRadius)+1;


run("Set Measurements...", "area limit display redirect=None decimal=0");
//  Fill Arrays: DistanceToCore, AreaTotal, AreaIncrease -------------------------------------------
selectWindow("ColorCoded (red)");
run("Select None");

for(i=1; i<=NrOfCircles; i++){
	toUnscaled(IncreaseRadius);
	makeOval(CenterOfMass_X-(IncreaseRadius*i)-r, CenterOfMass_Y-(IncreaseRadius*i)-r, 2*IncreaseRadius*i+d, 2*IncreaseRadius*i+d);
	setThreshold(0, 255);
	run("Measure");
	toScaled(IncreaseRadius);
	}
resetThreshold();

DistanceToCore=newArray(NrOfCircles);
AreaTotal=newArray(NrOfCircles);
AreaIncrease=newArray(NrOfCircles);
ThresholdedAreaIncrease=newArray(NrOfCircles);
Core_Area=newArray(NrOfCircles);
Migration_Area=newArray(NrOfCircles);


for(i=1; i<=NrOfCircles; i++) {
	DistanceToCore[i-1] = i * IncreaseRadius;
	AreaTotal[i-1] = getResult("Area",i-1);
	AreaIncrease[i-1] = AreaTotal[i-1] - OldArea;
	OldArea = AreaTotal[i-1];
}
selectWindow("Results");
run("Close");


// moet uiteindelijk een loop worden--------------------------------------------------------------------------------------
selectWindow("ColorCoded (green)");	
run("Select None");
run("Duplicate...", "title=tempGr");
for(i=1; i<=NrOfCircles; i++){
	toUnscaled(IncreaseRadius);
	makeOval(CenterOfMass_X-(IncreaseRadius*i)-r, CenterOfMass_Y-(IncreaseRadius*i)-r, 2*IncreaseRadius*i+d, 2*IncreaseRadius*i+d);
	setThreshold(Threshold, 255);
	run("Measure");
	run("Clear", "slice");
	toScaled(IncreaseRadius);

	ThresholdedAreaIncrease[i-1] = getResult("Area",i-1);
	Migration_Area[i-1] =  ThresholdedAreaIncrease[i-1] ;
	}

selectWindow("tempGr");
run("Make Inverse");
run("Cut");
selectWindow("ColorCoded (blue)");
run("Paste");
run("Select None");
selectWindow("tempGr");
run("Close");
//Array.show("Green", DistanceToCore, AreaTotal, AreaIncrease, ThresholdedAreaIncrease, Migration_Area);
//--------------------------------------------------------------------------------------------------------------------------------

selectWindow("MaxProjection");
run("Close");
selectWindow("temp");
run("Close");
selectWindow("Results");
run("Close");

run("Merge Channels...", "c1=[ColorCoded (red)] c2=[ColorCoded (green)] c3=[ColorCoded (blue)] create");
run("RGB Color");
Array.show("Results", DistanceToCore,  Migration_Area);